Einbindung DMS Factbox

Im unten angeführten Codebeispiel wird dargestellt, wie Sie die DMS Factbox in Ihre individuellen Seiten integrieren können:

pageextension XXXX "Page Ext" extends "Customer Card"
{
    layout
    {
        addfirst(factboxes)
        {
            part("Document Box"; "CCS UDC Document Fact Box")
            {
                ApplicationArea = All;
                Visible = FastSearchVisible;
            }
        }
    }

    actions
    {
        addlast(navigation)
        {
            group("DMS")
            {
                Caption = 'DMS';

                action("DMS Search")
                {
                    Tooltip = 'COSMO App';
                    ApplicationArea = All;
                    Image = Archive;
                    Promoted = true;
                    PromotedCategory = Process;
                    Visible = SearchVisible;
                    Caption = 'Documents';

                    trigger OnAction()
                    var
                        DMS: Codeunit "CCS UDC DMS Mgt.";
                    begin
                        GRecordRef.GetTable(Rec);
                        DMS.SearchDMSDocs(CurrPage.OBJECTID(FALSE), GRecordRef, TRUE, true);
                        "RefreshFastSearch"();
                    end;

                }
            }
        }
    }

    trigger OnOpenPage()
    begin
        SearchVisible := CurrPage."Document Box".Page.SearchVisible(CurrPage.OBJECTID(FALSE));
        FastSearchVisible := CurrPage."Document Box".Page.FastSearchAndDropBoxVisible(CurrPage.OBJECTID(FALSE));
    end;

    trigger OnAfterGetCurrRecord()
    begin
        if FastSearchVisible then begin
            if CurrPage."Document Box".Page.SetRec(Rec) then
                CurrPage."Document Box".Page.GetDocuments();
        end;
    end;

    procedure "RefreshFastSearch"()
    begin
        if FastSearchVisible then begin
                CurrPage."Document Box".Page.GetDocuments();
        end;
    end;

    var
        GRecordRef: RecordRef;
        SearchVisible: Boolean;
        FastSearchVisible: Boolean;
}