Required process steps to extend the 1ClickFactory Migration Tool  STEP 1 - Generating the Data Migration Temp. Tables App  STEP 2 - Generating the Upgrade App  STEP 3 - Extend the PowerShell scriptSpecial features for the Upgrade App

COSMO Guideline to extend the 1ClickFactory Migration Tool

To run the data upgrade process for database tables that are not fully included in the Migration Tool yet, follow the example on how to extend the upgrade process.

Required process steps to extend the 1ClickFactory Migration Tool

STEP 1 - Generating the Data Migration Temp. Tables App

Start creating all necessary temporary table objects, if not available, and create an own Data Migration Temp. Tables app.

Note

Ensure that

• full table schema is copied,
• field/trigger source code is removed,
• flow fields are removed.

Below an example of a TEMP.Table.al file.

table 70859 "TEMP DMS - Setup"
{
    Caption = 'TEMP DMS - Setup';

    fields
    {
        field(1; "Primary Key"; Code[10])
        {
            DataClassification = CustomerContent;
            Caption = 'Primary Key';
        }
        field(50; "Upload Type"; Option)
        {
            DataClassification = CustomerContent;
            Caption = 'Upload Type';
            OptionCaption = ',Client,Queue';
            OptionMembers = ,"Client","Queue";
        }
        field(55; "File Duplicate Handling"; Option)
        {
            DataClassification = CustomerContent;
            Caption = 'SharePoint File Duplicate';
            OptionCaption = ',New Version,Add Timestamp on File Name';
            OptionMembers = ,"New Version","Timestamp";
        }
        field(60; "Report File Name Formula"; Text[250])
        {
            DataClassification = CustomerContent;
            Caption = 'Report File Name Formula';
        }
        field(61; "Report Upload Type"; Option)
        {
            DataClassification = CustomerContent;
            Caption = 'Report Upload Type';
            OptionCaption = ',Only Upload,Upload and Open,Upload and E-Mail';
            OptionMembers = ,"None","Open","Mail";
        }
        {...}
    }
    keys
    {
        key(Key1; "Primary Key")
        {
        }
    }
}

Now run the build task (Control + Shift + B) to create the final Data Migration Temp. Tables app and store the .app file in the $AppFolderPath directory.

STEP 2 - Generating the Upgrade App

For each COSMO product, an upgrade app must exist which contains only one codeunit to copy or move the temporary stored data to the target tables.

Start creating a new AL project with one codeunit. Ensure that the object number in the customer BC16 environment is available. List all dependent packages of the upgrade app within the .app file.

Below an example of a DataMigration.Codeunit.al file.

codeunit 79999 "COSMO Data Migration"
{
    trigger OnRun()
    begin
        // Call of the start procedure 
        StartDataMigration();
    end;

    local procedure StartDataMigration()
    begin
        // Call of migration procedure(s)
        MigDataFromT70859ToT5306000(); 
        MigDataFromT70861ToT5306010();
    end;

    /// <summary>
    /// Migrate data from the "TEMP DMS - Setup" table to the target "CCS DMS Setup" table.
    /// </summary>
    local procedure MigDataFromT70859ToT5306000()
    var
        FromT70859: Record "TEMP DMS - Setup";
        ToT5306000: Record "CCS DMS Setup";
    begin
        if FromT70859.FindFirst() then begin
            Clear(ToT5306000);
            ToT5306000.Reset();
            ToT5306000.Init();

            if FromT70859."Report File Name Formula" = '' then
                ToT5306000."Report File Name Formula" := '[RecordId] - [ReportId] - [Today] [Time].pdf'
            else
                ToT5306000."Report File Name Formula" := FromT70859."Report File Name Formula";

            case FromT70859."File Duplicate Handling" of
                FromT70859."File Duplicate Handling"::"New Version":
                    ToT5306000."Duplicate Handling" := ToT5306000."Duplicate Handling"::Versioning;
                FromT70859."File Duplicate Handling"::Timestamp:
                    ToT5306000."Duplicate Handling" := ToT5306000."Duplicate Handling"::Timestamp;
                else
                    ToT5306000."Duplicate Handling" := ToT5306000."Duplicate Handling"::Setup;
            end;

            ToT5306000."App. Area DMS BaseApp" := true;
            if not ToT5306000.Insert(true) then ToT5306000.Modify(true);
        end;
    end;

    [...]
}

Note

It is also possible to migrate data from extended Base Application tables.

Run the build task (Control + Shift + B) to create the final COSMO Data Migration Tool STEP2 app and store the .app file in the $AppFolderPath directory.

STEP 3 - Extend the PowerShell script

Within each performance package, a .ps1 file with all PowerShell commands is available. The basic process remains the same, only the tasks below require additions.

...
# Install Data Migration Temp. Tables App(s)
# Restart Server Instance
# Install COSMO Target Extension(s)
# Run COSMO App(s) Data Upgrade STEP2
# Remove Data Migration Temp. Tables App(s)
...

Extend the PowerShell script with the corresponding script lines for the COSMO extension and process the upgrade based on the UpgradeImplementationGuidelines.pdf.

# Install Data Migration Temp. Tables App(s)
Publish-NAVApp -ServerInstance $BC160ServerInstance -Path "$AppFolderPath\Cosmo Consult_COSMO DMS Data Migration Temp. Tables_1.0.0.0.app" -SkipVerification
Sync-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO DMS Data Migration Temp. Tables"
Install-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO DMS Data Migration Temp. Tables"

# Restart Server Instance
Restart-NAVServerInstance -ServerInstance $BC160ServerInstance

# Install COSMO Target Extension(s)
Publish-NAVApp -ServerInstance $BC160ServerInstance -Path "$AppFolderPath\Cosmo Consult_COSMO Licensing_1.2.0.34119.app" -SkipVerification
Sync-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO Licensing"
Install-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO Licensing"

Publish-NAVApp -ServerInstance $BC160ServerInstance -Path "$AppFolderPath\Cosmo Consult_COSMO Document Management System_2.0.0.11032.app" -SkipVerification
Sync-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO Document Management System"
Install-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO Document Management System"

# Run COSMO App(s) Data Upgrade STEP2
Publish-NAVApp -ServerInstance $BC160ServerInstance -Path "$AppFolderPath\Cosmo Consult_COSMO Document Management System Data Migration Tool STEP2_1.0.0.0.app" -SkipVerification
Sync-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO Document Management System Data Migration Tool STEP2"
Install-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO Document Management System Data Migration Tool STEP2"
Get-NAVCompany -ServerInstance $BC160ServerInstance | % { Invoke-NAVCodeunit -ServerInstance $BC160ServerInstance -CodeunitId 70005 -CompanyName $_.CompanyName }
Uninstall-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO Document Management System Data Migration Tool STEP2"
Unpublish-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO Document Management System Data Migration Tool STEP2"

# Remove Data Migration Temp. Tables App(s)
Uninstall-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO DMS Data Migration Temp. Tables"
Unpublish-NAVApp -ServerInstance $BC160ServerInstance -Name "COSMO DMS Data Migration Temp. Tables"
Get-NAVAppInfo -ServerInstance $BC160ServerInstance

Special features for the Upgrade App

There are two options to start the upgrade codeunit from the PowerShell script.

First, you can invoke the OnRun() trigger using the follwoing PowerShell command.

Invoke-NAVCodeunit -ServerInstance $BC160ServerInstance -CompanyName $MyCompanyName -CodeunitId $MyCodeunitID 

codeunit 79999 "COSMO Data Migration"
{
    trigger OnRun()
    begin
        // Call of the start procedure 
        StartDataMigration();
    end;
}

Second, you can invoke a procedure using the follwoing PowerShell command.

$MyArguments = 'DMS365 _00000000-0000-0000-0000-000000000000 _my365.sharepoint.com _00000000-0000-0000-0000-000000000000 _************ _https://my365.sharepoint.com'
$MyCodeunitID = 5306701
$MyMethodName = "StartDMSDataMigration" 
Invoke-NAVCodeunit -ServerInstance $BC160ServerInstance -CompanyName $MyCompanyName -CodeunitId $MyCodeunitID -MethodName $MyMethodName -Argument $MyArguments 

The second makes it possible to include external data within $MyArguments.

codeunit 5306701 "COSMO DMS Data Migration"
{
    procedure StartDMSDataMigration(ValueText: Text)
    var
        ToT5306002: Record "CCS DMS Credential";
        SplittedValue: List of [Text];
        i: Integer;
    begin
        Clear(ToT5306002);
        ToT5306002.Reset();

        SplittedValue := ValueText.Split('_');
        if SplittedValue.Count > 0 then begin
            ToT5306002.Init();
            ToT5306002.Code := SplittedValue.Get(1).Trim(); // 'DMS365'
            ToT5306002.Realm := SplittedValue.Get(2).Trim(); // '00000000-0000-0000-0000-000000000000'
            ToT5306002."Target Host" := SplittedValue.Get(3).Trim(); // 'my365.sharepoint.com'
            ToT5306002."App Client Id" := SplittedValue.Get(4).Trim(); // '00000000-0000-0000-0000-000000000000'
            ToT5306002.SetClientSecret(SplittedValue.Get(5).Trim());
            // ToT5306002."App Client Secret Key" := CreateGuid();
            // IsolatedStorage.Set(ToT5306002."App Client Secret Key", SplittedValue.Get(5).Trim()); // '********'
            ToT5306002.Insert();

            FilterServerUrl := SplittedValue.Get(6).Trim(); // 'https://my365.sharepoint.com'
            FilterCredentialCode := ToT5306002.Code;
        end else
            exit;

        StartDataMigration();
        ValidateDataMigration();
    end;

    var
        FilterServerUrl: Text;
        FilterCredentialCode: Code[20];

    local procedure StartDataMigration()
    begin
        MigDataFromT70859(); // Migrate Setup
        MigDataFromT70861(FilterServerUrl, FilterCredentialCode); // Migrate Document Libraries, Fields, Content Types, Table Setup, Metadata, Filters, ...
    end;

    local procedure ValidateDataMigration()
    var
        ToT5306010: Record "CCS DMS Document Library";
        ToT5306020: Record "CCS DMS Table Setup";
    begin
        if ToT5306010.FindSet() then
            repeat
                ToT5306010.Update(); // Update Document Libraries
            until ToT5306010.Next() = 0;

        if ToT5306020.FindSet() then
            repeat
                if ToT5306020.Status = ToT5306020.Status::Open then
                    ToT5306020.Release(); // Release all Table Setups
            until ToT5306020.Next() = 0;
    end;