Interface CCS REN Invoice Period Calculation

interface "CCS REN Invoice Period Calculation"

This interface can be used when the ENUM 5072455 "CCS REN Invoice Period" is extended to use a specific Invoice Period instead of the default periods.

Methods

GetEndDateExpression

public "CCS REN Invoice Period Calculation" GetEndDateExpression(StartDate: Date; QtyOfPeriods: Integer): Text

Returns a date expression based on the provided start date and quantity of periods to calculate an end date for the whole invoice period.

Parameters
Name Type Description
StartDate Date Specifies the starting date for the calculation.
QtyOfPeriods Integer Specifies the number of periods to calculate.
Return Value

Text

GetDateStepsExpression

public "CCS REN Invoice Period Calculation" GetDateStepsExpression(CalendarBased: Boolean; PeriodStart: Date): Text

Returns an expression to compute the invoice period based on whether the calculation is calendar based. Note that calendar based calculations are currently not supported for day and week. If you are implementing a week or day based period, you can leave that procedure empty.

Parameters
Name Type Description
CalendarBased Boolean Specifies if the calculation is based on a calendar.
PeriodStart Date Specifies the start date of the period.
Return Value

Text

GetDateExpressionForward

public "CCS REN Invoice Period Calculation" GetDateExpressionForward(CalendarBased: Boolean; PeriodStart: Date; PreparedCalcFormula: Text; EndDate: Date; InvoiceToDate: Date): Text

Returns a date expression for forward calculation of the next date within one step of the invoice period.

Parameters
Name Type Description
CalendarBased Boolean Specifies if the calculation is based on a calendar.
PeriodStart Date Specifies the start date of the period.
PreparedCalcFormula Text Specifies the prepared calculation formula.
EndDate Date Specifies the end date for the calculation.
InvoiceToDate Date Specifies the date to which the invoice is calculated.
Return Value

Text

GetDateExpressionBackward

public "CCS REN Invoice Period Calculation" GetDateExpressionBackward(CalendarBased: Boolean; StartDate: Date): CalcFormula: Text

Returns a date expression for forward calculation of the next date within one step of the invoice period.

Parameters
Name Type Description
CalendarBased Boolean Specifies if the calculation is based on a calendar.
StartDate Date Specifies the starting date for stepping backwards.
Return Value

Text

IsCalendarBased

public "CCS REN Invoice Period Calculation" IsCalendarBased(): Boolean

Returns if the calculation is based on a calendar. Day or week based calculations must not be calendar based.

Return Value

Boolean

Returns true if the calculation is calendar based, otherwise false.

Example

The following example shows an implementation for the invoice period of three weeks and three years:

enumextension 50100 "My Own Invoice Period" extends "CCS REN Invoice Period"
{

    value(50100; "Three Weeks")
    {
        Caption = 'Three Weeks';
        Implementation = "CCS REN Invoice Period Calculation" = "Invoice Period Calc. Three W.";
    }
    value(50101; "Three Years")
    {
        Caption = 'Three Years';
        Implementation = "CCS REN Invoice Period Calculation" = "Invoice Period Calc. Three Y.";
    }
}

codeunit 50101 "Invoice Period Calc. Three W." implements "CCS REN Invoice Period Calculation"
{

    procedure GetEndDateExpression(StartDate: Date; QtyOfPeriods: Integer): Text
    begin
        exit(StrSubstNo('<+%3W-1D>', Format(QtyOfPeriods)));
    end;

    procedure GetDateStepsExpression(CalendarBased: Boolean; PeriodStart: Date): Text
    begin

    end;

    procedure GetDateExpressionForward(CalendarBased: Boolean; PeriodStart: Date; PreparedCalcFormula: Text; EndDate: Date; InvoiceToDate: Date): Text
    begin
        exit('<+3W-1D>');
    end;

    procedure GetDateExpressionBackward(CalendarBased: Boolean; StartDate: Date): Text
    begin
        exit('<-3W+1D>');
    end;

    procedure IsCalendarBased(): Boolean
    begin
        exit(false)
    end;

}


codeunit 50102 "Invoice Period Calc. Three Y." implements "CCS REN Invoice Period Calculation"
{

    procedure GetEndDateExpression(StartDate: Date; QtyOfPeriods: Integer): Text
    begin
        exit(StrSubstNo('<+%3Y-1D>', Format(QtyOfPeriods)));
    end;

    procedure GetDateStepsExpression(CalendarBased: Boolean; PeriodStart: Date): Text
    begin
        if CalendarBased then
            exit('<+CY+3Y>');
    end;

    procedure GetDateExpressionForward(CalendarBased: Boolean; PeriodStart: Date; PreparedCalcFormula: Text; EndDate: Date; InvoiceToDate: Date): Text
    begin
        if CalendarBased then
            exit('<3Y>')
        else
            exit('<+3Y-1D>');
    end;

    procedure GetDateExpressionBackward(CalendarBased: Boolean; StartDate: Date): Text
    begin
        if CalendarBased then
            exit('<CY-3Y>')
        else
            exit('<-3Y+1D>');
    end;

    procedure IsCalendarBased(): Boolean
    begin
        exit(true);
    end;

}